Arduino 基礎篇 - 數位輸入輸出，按鈕亮燈

應用：
1. 讀取 A0 - A7 的 Analog Input 類比輸入參數值（指撥開關狀態 High 或 Low）。
2. 當讀取的 Analog Input 類比輸入參數值 低於 1/2 參考電壓，
    則設定輸出腳位為 "LOW" ，LED 燈滅
2. 當讀取的 Analog Input 類比輸入參數值 高於 1/2 參考電壓，
    則設定輸出腳位為 "HIGH" ，LED 燈亮


範例：按鈕亮燈 （指撥開關 On/Off 亮 LED 燈 ）
（讀取 A0-A7 按鈕狀態，設定 LED0-LED7  亮或滅）
==================================================
// 定義 輸出 LED 腳位 號碼，由 D2-D13 腳位
int LEDPin[] = { 2, 3, 4, 5, 6, 7, 8, 9 ,10, 11, 12, 13};
// 定義 輸入 DIP SW 腳位 號碼，由 A0-A7 腳位
//int SensorPin[] = { 14, 15, 16, 17, 18, 19, 20, 21 };
int SensorPin[] = { A0, A1, A2, A3, A4, A5, A6, A7 };

int delayMs = 10;   // 設定延遲時間
int SensorValue;

void setup() {
    // put your setup code here, to run once:
    // 初始化設定
    for (int LoopCount = 0; LoopCount <= 7; LoopCount++) {
         pinMode(LEDPin[LoopCount], OUTPUT);    // 設定輸出腳位
         pinMode(SensorPin[LoopCount], INPUT);  // 設定輸入腳位
         // Nano A6/A7 需要設定為 Input Analog Mode
    } 
     Serial.begin(9600);
}

void loop() {

  // put your main code here, to run repeatedly:
  for (int LoopCount = 0; LoopCount <= 7; LoopCount++) {

      // For Arduino Uno A0-A5 Digital Input
      //SensorValue = digitalRead(SensorPin[LoopCount]);
   
      // read the value from the sensor: For Nano A0-A7 Analog Pin
      SensorValue = analogRead(SensorPin[LoopCount]);

      // 透過 Serial Monitor Port 顯示輸入腳位 狀態 或 類比數值
      Serial.print("SensorPin[");
      Serial.print(LoopCount);
      Serial.print("] = Pin");
      Serial.print(SensorPin[LoopCount]);
      Serial.print(" = ");
      Serial.print(SensorValue);
      Serial.print(" --> ");
   
      if ( SensorValue > 512 ) {
        // 當 Analog Input 類比輸入高於 1/2 電壓時，設定為 LOW Lever 輸出
        // 因為目前的實驗板 Analog Input 有加 Pull High 上拉電阻，
        // 所以 DIP SW 撥到 On 時，Analog Input 類比輸入為 低準位 LOW
        digitalWrite(LEDPin[LoopCount], LOW);
      }     
       else {
        // 否則，當 Analog Input 類比輸入低於 1/2 電壓時，設定為 HIGH Lever 輸出
        digitalWrite(LEDPin[LoopCount], HIGH);
      }   
   
      // 透過 Serial Monitor Port 顯示輸出腳位 狀態 或 類比數值
      Serial.print("LEDPin[");
      Serial.print(LoopCount);
      Serial.print("] = ");
      Serial.print(SensorValue);
      Serial.println(""); 
 
    delay(delayMs);   // 延遲一段 delayMs 設定的週期時間
 
  }   // for (int LoopCount = 0; LoopCount <= 7; LoopCount++) {

}

==================================================
（程式範例結束）

DIP SW 1,3,6,8 On; LED 1,3,6,8 亮 

DIP SW 1,2,4,8 On; LED 1,2,4,8 亮

Arduino 基礎篇 - 數位輸出，跑馬燈

Arduino 市面有幾款常常可以看到的版本，例如 Arduino UNO/Nano/MEGA2560...
相關產品的基本介紹，網路上有許多介紹，不妨上網搜尋一下～
至於使用那一個 Arduino 版本來學習，參考如下：

Arduino UNO - 網上範例最多，大部分範例均運用 Arduino Uno 為主
=========================================================
Digital I/O 數位輸入/輸出端共 14Pin（ 0~13）（其中包含 6 組 PWM 端子）
Analog I/O 類比輸入/輸出端共  6Pin （A0~A5）。
支援 AREF 端子。
通信 UART Tx/Rx 端子
支援 USB 轉 TTL Tx/Rx 端子

Arduino Nano - 體積小，比 UNO 多了 A6/A7 Analog I/O 類比輸入端子
=========================================================
Digital I/O 數位輸入/輸出端共 14Pin（ 0~13）（其中包含 6 組 PWM 端子）
Analog I/O 類比輸入/輸出端共  8Pin （A0~A7）。
支援 AREF 端子。
通信 UART Tx/Rx 端子
支援 USB 轉 TTL Tx/Rx 端子

Arduino MEGA2560 - 4 組 UART 通信接口，比其他版本多了 許多 I/O 端口
=========================================================
Digital I/O 數位輸入/輸出端共 54Pin（其中包含 15 組 PWM 端子）
Analog I/O 類比輸入/輸出端共  16Pin （A0~A15）。
支援 AREF 端子。
通信 UART Tx/Rx 端子 4 組
支援 USB 轉 TTL Tx/Rx 端子

所以一般運用，個人比較建議使用 Arduino Nano，因為 體積小；
又有比較多的 I/O 端子可以運用，例如 ：8 Input / 12 Output 的運用。

詳細 Arduino 硬體規格運用再請上網搜尋。
～～～～～～～～～～～～～～～～～～～～

如何控制 Arduino 來做運用，就需要下載/安裝 Arduino IDE 開發程式 （參考 https://www.arduino.cc/en/Main/Software） 及程式撰寫。

Arduino 程式架構可以分為二大類：
一。為 void setup ()；宣告 Arduino 的初始化設定
二。為 void loop ()；撰寫  Arduino 主程式開始的迴圈

一。為 void setup ()，Arduino 的初始化設定，例如 ：
1. Arduino 硬體狀態設定：
    pinMode (腳位代號, 輸出或輸入模式);    // 腳位設定為輸出腳或輸入腳
2. Arduino 的程式初始化設定：（設定程式一開始的狀態）
    digitalWrite (腳位代號, 輸出準位狀態設定);


二。為 void loop ()，主程式開始的迴圈，例如：

    digitalWrite (腳位代號, HIGH);// 輸出狀態
    delay (10); // Delay 的延遲單位時間為 ms
// 所以 delay (10); 代表延遲 10ms
    digitalWrite (腳位代號, LOW);
    delay (20); // Delay 的延遲單位時間為 ms
// 所以 delay (20); 代表延遲 20ms

int PinNumber; 宣告 PinNumber 變數為

    for (int PinNumber = 2; PinNumber <= 9; PinNumber++)
    // PinNumber 代表 腳位代號；腳位由 第 2 腳開始到第 9 腳；
 
.......................


範例：LED 跑馬燈 （控制 D2 - D13 LED 亮或滅）
=======================================
// 定義 輸出 LED 腳位 號碼，由 D2-D13 腳位
int LEDPin[] = { 2, 3, 4, 5, 6, 7, 8, 9 ,10, 11, 12, 13};
/*
 * 詳細上列定義 LEDPin 陣列內容：
 * LEDPin[0] = 2; 第 D2 腳位
 * LEDPin[1] = 3; 第 D3 腳位
 * LEDPin[2] = 4; 第 D4 腳位
 * LEDPin[3] = 5; 第 D5 腳位
 * LEDPin[4] = 6; 第 D6 腳位
 * LEDPin[5] = 7; 第 D7 腳位
 * LEDPin[6] = 8; 第 D8 腳位
 * LEDPin[7] = 9; 第 D9 腳位
 */
int delayMs = 50;   // 設定延遲時間
int LED_Status = 1; // 設定 LED 亮燈方向。亮燈方向累加 = 1；亮燈方向累減 = 0
int LED_OnNumber = 0; // 設定亮燈的號碼，由 0 ～ 7。

void setup() {
  // put your setup code here, to run once:
    for (int LoopCount = 0; LoopCount <= 11; LoopCount++) {
         pinMode(LEDPin[LoopCount], OUTPUT);  // 設定 LEDPin[] 腳位為 輸出腳位
    }
    Serial.begin(9600);   // 設定 Serial Port 鮑率 (Baudrate) = 9600
}

void loop() {

  // put your main code here, to run repeatedly:
  for (int LoopCount = 0; LoopCount <= 11; LoopCount++) {
    digitalWrite(LEDPin[LoopCount], LoopCount == LED_OnNumber ? HIGH : LOW); 
  }

  if (LED_Status == 1 )   // 設定 LED 亮燈方向。亮燈方向累加 = 1
    LED_OnNumber++; 
  else if (LED_Status == 0 )    // 設定 LED 亮燈方向。亮燈方向累減 = 0
    LED_OnNumber--;   

  if (LED_OnNumber == 11)   // 亮燈號碼到最末號碼，則設定 LED 亮燈方向。亮燈方向累減 = 0
    LED_Status = 0;
  else if (LED_OnNumber == 0)   // 亮燈號碼到最初號碼，設定 LED 亮燈方向。亮燈方向累加 = 1
    LED_Status = 1;
 
  // 透過 Serial Monitor 將目前狀態傳送出來顯示
  Serial.print("LED_Status = ");
  Serial.print(LED_Status);
  Serial.print(", LED_OnNumber = ");
  Serial.print(LED_OnNumber);
  Serial.println("");
 
  delay(delayMs);   // 延遲一段 delayMs 設定的週期時間
 
}

=======================================
（程式範例結束）